plugins {
    id 'com.android.application'
    id 'com.google.gms.google-services'
    id 'io.fabric'
    id 'kotlin-android'
    id 'kotlin-android-extensions'
    id 'kotlin-kapt'
    id 'org.jmailen.kotlinter'
    id 'com.github.ben-manes.versions' version '0.25.0'
    id 'io.gitlab.arturbosch.detekt' version '1.0.1'
}

android {
    compileSdkVersion 28
    buildToolsVersion '28.0.3'

    defaultConfig {
        applicationId "net.thauvin.erik.android.tesremoteprogrammer"
        minSdkVersion 26
        targetSdkVersion 28
        versionCode 1
        versionName "1.0-alpha"
        buildConfigField "long", "TIMESTAMP", System.currentTimeMillis()  + "L"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    sourceSets {
        main.java.srcDirs += 'src/main/kotlin'
        test.resources.srcDirs += 'src/test/res'
    }

    lintOptions {
        baseline file("lint-baseline.xml")
    }
}

ext {
    anko_version = '0.10.8'
    support_version = "28.0.0"
    perms_dispatch_version = "4.5.0"
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    implementation 'com.google.firebase:firebase-analytics:17.2.0'
    implementation 'com.crashlytics.sdk.android:crashlytics:2.10.1'

    implementation 'androidx.legacy:legacy-support-v13:1.0.0'
    implementation 'androidx.appcompat:appcompat:1.1.0'

    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    implementation "org.jetbrains.anko:anko-sdk23:$anko_version"
    implementation "org.jetbrains.anko:anko-appcompat-v7:$anko_version"
    implementation "org.jetbrains.anko:anko-support-v4:$anko_version"
    implementation "org.jetbrains.anko:anko-design:$anko_version"

    implementation 'com.google.android.material:material:1.0.0'

    implementation group: 'com.google.code.gson', name: 'gson', version: '2.8.5'

    // https://github.com/JakeWharton/ViewPagerIndicator
    implementation 'fr.avianey.com.viewpagerindicator:library:2.4.1.1@aar'

    // https://github.com/hotchemi/PermissionsDispatcher
    implementation "org.permissionsdispatcher:permissionsdispatcher:$perms_dispatch_version"
    kapt "org.permissionsdispatcher:permissionsdispatcher-processor:$perms_dispatch_version"

    // https://github.com/medyo/android-about-page
    implementation 'com.github.medyo:android-about-page:1.2.5'

    testImplementation 'junit:junit:4.12'
}

repositories {
    mavenCentral()
    maven { url "https://jitpack.io" }
}

kapt {
    //generateStubs = true
}

kotlinter {
    ignoreFailures = false
    reporters = ['html', 'plain']
    experimentalRules = false
    disabledRules = ['import-ordering']
}

detekt {
    input = files("src/main/java")
    filters = ".*/resources/.*,.*/build/.*"
    baseline = file("detekt-baseline.xml")
}