Initial commit.

2022-12-30 17:45:42 -08:00 · 2022-12-30 17:45:42 -08:00 · a3645937ca
commit a3645937ca
23 changed files with 1199 additions and 0 deletions
--- a/lib/build.gradle.kts
+++ b/lib/build.gradle.kts
@ -0,0 +1,170 @@
+import org.gradle.api.tasks.testing.logging.TestExceptionFormat
+import org.gradle.api.tasks.testing.logging.TestLogEvent
+import org.jetbrains.dokka.gradle.DokkaTask
+import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
+
+plugins {
+    id("com.github.ben-manes.versions") version "0.44.0"
+    id("io.gitlab.arturbosch.detekt") version "1.22.0"
+    id("java")
+    id("java-library")
+    id("maven-publish")
+    id("org.jetbrains.dokka") version "1.7.20"
+    id("org.jetbrains.kotlin.jvm") version "1.8.0"
+    id("org.jetbrains.kotlinx.kover") version "0.6.1"
+    id("org.sonarqube") version "3.5.0.2730"
+    id("signing")
+}
+
+description = "URL parameters encoding and decoding"
+group = "net.thauvin.erik"
+version = "0.9-SNAPSHOT"
+
+val deployDir = "deploy"
+val gitHub = "ethauvin/$name"
+val mavenUrl = "https://github.com/$gitHub"
+val publicationName = "mavenJava"
+
+repositories {
+    mavenCentral()
+    maven { url = uri("https://oss.sonatype.org/content/repositories/snapshots") }
+}
+
+dependencies {
+    testImplementation(kotlin("test"))
+}
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_11
+    targetCompatibility = JavaVersion.VERSION_11
+    withSourcesJar()
+}
+
+sonarqube {
+    properties {
+        property("sonar.projectKey", "ethauvin_$name")
+        property("sonar.organization", "ethauvin-github")
+        property("sonar.host.url", "https://sonarcloud.io")
+        property("sonar.sourceEncoding", "UTF-8")
+        property("sonar.coverage.jacoco.xmlReportPaths", "${project.buildDir}/reports/kover/xml/report.xml")
+    }
+}
+
+val javadocJar by tasks.creating(Jar::class) {
+    dependsOn(tasks.dokkaJavadoc)
+    from(tasks.dokkaJavadoc)
+    archiveClassifier.set("javadoc")
+}
+
+tasks {
+    withType<KotlinCompile>().configureEach {
+        kotlinOptions.jvmTarget = java.targetCompatibility.toString()
+    }
+
+    withType<Test> {
+        testLogging {
+            exceptionFormat = TestExceptionFormat.FULL
+            events = setOf(TestLogEvent.PASSED, TestLogEvent.SKIPPED, TestLogEvent.FAILED)
+        }
+    }
+
+    withType<GenerateMavenPom> {
+        destination = file("$projectDir/pom.xml")
+    }
+
+    clean {
+        doLast {
+            project.delete(fileTree(deployDir))
+        }
+    }
+
+    withType<DokkaTask>().configureEach {
+        dokkaSourceSets {
+            named("main") {
+                moduleName.set("UrlEncoder API")
+            }
+        }
+    }
+
+    val copyToDeploy by registering(Copy::class) {
+        from(configurations.runtimeClasspath) {
+            exclude("annotations-*.jar")
+        }
+        from(jar)
+        into(deployDir)
+    }
+
+    register("deploy") {
+        description = "Copies all needed files to the $deployDir directory."
+        group = PublishingPlugin.PUBLISH_TASK_GROUP
+        dependsOn(clean, build, jar)
+        outputs.dir(deployDir)
+        inputs.files(copyToDeploy)
+        mustRunAfter(clean)
+    }
+
+    jar {
+        archiveBaseName.set(rootProject.name)
+    }
+
+    "sonarqube" {
+        dependsOn(koverReport)
+    }
+}
+
+publishing {
+    publications {
+        create<MavenPublication>(publicationName) {
+            from(components["java"])
+            artifactId = rootProject.name
+            artifact(javadocJar)
+            pom {
+                name.set(rootProject.name)
+                description.set(project.description)
+                url.set(mavenUrl)
+                licenses {
+                    license {
+                        name.set("The Apache License, Version 2.0")
+                        url.set("http://www.apache.org/licenses/LICENSE-2.0.txt")
+                    }
+                }
+                developers {
+                    developer {
+                        id.set("gbevin")
+                        name.set("Geert Bevin")
+                        email.set("gbevin@uwyn.com")
+                    }
+                    developer {
+                        id.set("ethauvin")
+                        name.set("Erik C. Thauvin")
+                        email.set("erik@thauvin.net")
+                        url.set("https://erik.thauvin.net/")
+                    }
+                }
+                scm {
+                    connection.set("scm:git:git://github.com/$gitHub.git")
+                    developerConnection.set("scm:git:git@github.com:$gitHub.git")
+                    url.set(mavenUrl)
+                }
+                issueManagement {
+                    system.set("GitHub")
+                    url.set("$mavenUrl/issues")
+                }
+            }
+        }
+    }
+    repositories {
+        maven {
+            name = "ossrh"
+            url = if (project.version.toString().contains("SNAPSHOT"))
+                uri("https://oss.sonatype.org/content/repositories/snapshots/") else
+                uri("https://oss.sonatype.org/service/local/staging/deploy/maven2/")
+            credentials(PasswordCredentials::class)
+        }
+    }
+}
+
+signing {
+    useGpgCmd()
+    sign(publishing.publications[publicationName])
+}