8890fef665
* bump Kotlin to 1.9.23, enable additional Kotlin Multiplatform targets * replace soon-to-be-deprecated kotlinOptions with newer compilerOptions
90 lines
3.6 KiB
Kotlin
90 lines
3.6 KiB
Kotlin
rootProject.name = "urlencoder"
|
|
|
|
pluginManagement {
|
|
repositories {
|
|
mavenCentral()
|
|
gradlePluginPortal()
|
|
}
|
|
}
|
|
|
|
@Suppress("UnstableApiUsage")
|
|
dependencyResolutionManagement {
|
|
repositoriesMode.set(RepositoriesMode.PREFER_SETTINGS)
|
|
|
|
repositories {
|
|
mavenCentral()
|
|
maven("https://oss.sonatype.org/content/repositories/snapshots") {
|
|
name = "Sonatype Snapshots"
|
|
mavenContent { snapshotsOnly() }
|
|
}
|
|
|
|
// Declare the Node.js & Yarn download repositories
|
|
exclusiveContent {
|
|
forRepositories(
|
|
ivy("https://nodejs.org/dist/") {
|
|
name = "Node Distributions at $url"
|
|
patternLayout { artifact("v[revision]/[artifact](-v[revision]-[classifier]).[ext]") }
|
|
metadataSources { artifact() }
|
|
},
|
|
ivy("https://nodejs.org/download/v8-canary/") {
|
|
name = "Node Canary Distributions at $url"
|
|
patternLayout { artifact("v[revision]/[artifact](-v[revision]-[classifier]).[ext]") }
|
|
metadataSources { artifact() }
|
|
},
|
|
ivy("https://nodejs.org/download/nightly/") {
|
|
name = "Node Nightly Distributions at $url"
|
|
patternLayout { artifact("v[revision]/[artifact](-v[revision]-[classifier]).[ext]") }
|
|
metadataSources { artifact() }
|
|
},
|
|
)
|
|
filter { includeGroup("org.nodejs") }
|
|
}
|
|
|
|
exclusiveContent {
|
|
forRepository {
|
|
ivy("https://github.com/yarnpkg/yarn/releases/download") {
|
|
name = "Yarn Distributions at $url"
|
|
patternLayout { artifact("v[revision]/[artifact](-v[revision]).[ext]") }
|
|
metadataSources { artifact() }
|
|
}
|
|
}
|
|
filter { includeGroup("com.yarnpkg") }
|
|
}
|
|
|
|
// workaround for https://youtrack.jetbrains.com/issue/KT-51379
|
|
exclusiveContent {
|
|
forRepository {
|
|
ivy("https://download.jetbrains.com/kotlin/native/builds") {
|
|
name = "Kotlin Native"
|
|
patternLayout {
|
|
// example download URLs:
|
|
// https://download.jetbrains.com/kotlin/native/builds/releases/1.7.20/linux-x86_64/kotlin-native-prebuilt-linux-x86_64-1.7.20.tar.gz
|
|
// https://download.jetbrains.com/kotlin/native/builds/releases/1.7.20/windows-x86_64/kotlin-native-prebuilt-windows-x86_64-1.7.20.zip
|
|
// https://download.jetbrains.com/kotlin/native/builds/releases/1.7.20/macos-x86_64/kotlin-native-prebuilt-macos-x86_64-1.7.20.tar.gz
|
|
listOf(
|
|
"macos-x86_64",
|
|
"macos-aarch64",
|
|
"osx-x86_64",
|
|
"osx-aarch64",
|
|
"linux-x86_64",
|
|
"windows-x86_64",
|
|
).forEach { os ->
|
|
listOf("dev", "releases").forEach { stage ->
|
|
artifact("$stage/[revision]/$os/[artifact]-[revision].[ext]")
|
|
}
|
|
}
|
|
}
|
|
metadataSources { artifact() }
|
|
}
|
|
}
|
|
filter { includeModuleByRegex(".*", ".*kotlin-native-prebuilt.*") }
|
|
}
|
|
}
|
|
}
|
|
|
|
enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")
|
|
|
|
include(
|
|
":urlencoder-app",
|
|
":urlencoder-lib",
|
|
)
|